Properly add pegasus-fe-git

Signed-off-by: Severin Kaderli <severin@kaderli.dev>

pegasus-fe-git/.SRCINFO

@@ -0,0 +1,28 @@
+pkgbase = pegasus-fe-git
+	pkgdesc = A cross platform, customizable graphical frontend for launching emulators and managing your game collection.
+	pkgver = alpha11.r100.ga1f400c
+	pkgrel = 1
+	url = https://pegasus-frontend.org/
+	arch = i686
+	arch = x86_64
+	license = GPL3
+	makedepends = git
+	makedepends = qt5-tools
+	depends = qt-gstreamer
+	depends = qt5-svg
+	depends = qt5-multimedia
+	depends = qt5-gamepad
+	depends = qt5-graphicaleffects
+	provides = pegasus-fe
+	conflicts = pegasus-fe
+	source = pegasus-fe::git+https://github.com/mmatyas/pegasus-frontend.git
+	source = git+https://github.com/mmatyas/pegasus-frontend-translations.git#branch=master
+	source = git+https://github.com/mmatyas/pegasus-theme-grid.git
+	source = git+https://github.com/mmatyas/SortFilterProxyModel.git
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+	md5sums = SKIP
+
+pkgname = pegasus-fe-git
+

pegasus-fe-git/.gitignore

@@ -0,0 +1,7 @@
+pegasus-fe-git*
+pegasus-fe/
+pegasus-frontend-translations/
+pegasus-theme-grid/
+pkg/
+SortFilterProxyModel/
+src/

pegasus-fe-git/PKGBUILD

@@ -0,0 +1,62 @@
+# Maintainer: Severin Kaderli <severin.kaderli@gmail.com>
+_pkgname=pegasus-fe
+pkgname=${_pkgname}-git
+pkgver=alpha11.r100.ga1f400c
+pkgrel=1
+pkgdesc="A cross platform, customizable graphical frontend for launching emulators and managing your game collection."
+arch=('i686' 'x86_64')
+url="https://pegasus-frontend.org/"
+license=('GPL3')
+makedepends=(
+    'git'
+    'qt5-tools'
+)
+depends=(
+    'qt-gstreamer'
+    'qt5-svg'
+    'qt5-multimedia'
+    'qt5-gamepad'
+    'qt5-graphicaleffects'
+)
+provides=('pegasus-fe')
+conflicts=('pegasus-fe')
+source=(
+    "${_pkgname}::git+https://github.com/mmatyas/pegasus-frontend.git"
+    "git+https://github.com/mmatyas/pegasus-frontend-translations.git#branch=master"
+    "git+https://github.com/mmatyas/pegasus-theme-grid.git"
+    "git+https://github.com/mmatyas/SortFilterProxyModel.git"
+)
+md5sums=(
+    'SKIP'
+    'SKIP'
+    'SKIP'
+    'SKIP'
+)
+
+pkgver() {
+    cd "${_pkgname}"
+    git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+    cd "${srcdir}/${_pkgname}"
+    git submodule init
+    git config submodule.lang.url "${srcdir}/pegasus-frontend-translations"
+    git config submodule.src/themes/pegasus-theme-grid.url "${srcdir}/pegasus-theme-grid"
+    git config submodule.thirdparty/SortFilterProxyModel.url "${srcdir}/SortFilterProxyModel"
+    git submodule update
+}
+
+build() {
+    cd "${srcdir}/${_pkgname}"
+    mkdir -p ./build && cd build
+    qmake ..
+    make
+}
+
+package() {
+    cd "${srcdir}/${_pkgname}"
+    install -Dm755 "build/src/app/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+    install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+    install -Dm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}